t3code-flake/packages/t3code-desktop/default.nix

{
  lib,
  src,
  asar,
  stdenv,
  symlinkJoin,
  bun,
  codex ? null,
  claudeCode ? null,
  electron_40,
  gcc,
  git,
  gnumake,
  makeWrapper,
  node-gyp,
  nodejs,
  opencode ? null,
  pkg-config,
  python3,
  writableTmpDirAsHomeHook,
  withClaudeCode ? false,
  withCodex ? false,
  withOpencode ? false,
  xdg-utils,
}: let
  common = import ../common.nix {
    inherit
      lib
      stdenv
      bun
      nodejs
      writableTmpDirAsHomeHook
      ;
  };
  desktopPackageJson = lib.importJSON "${src}/apps/desktop/package.json";

  pname = "t3code-desktop";
  version = desktopPackageJson.version;
  basePackage = stdenv.mkDerivation (finalAttrs: {
    inherit pname version;
    inherit src;

    strictDeps = true;
    patches = [./desktop-nix-autoupdate.patch];

    nodeModules = common.mkNodeModules {
      inherit (finalAttrs) pname version src;
      outputHash = "sha256-vOCDwW/t7CbqHyeDE6Nvnlq0c9NO5T/2h1NJKLERGSs=";
      filters = [
        "."
        "./apps/desktop"
        "./apps/server"
        "./apps/web"
        "./packages/client-runtime"
        "./packages/contracts"
        "./packages/effect-acp"
        "./packages/effect-codex-app-server"
        "./packages/shared"
      ];
      impureEnvVars =
        lib.fetchers.proxyImpureEnvVars
        ++ [
          "GIT_PROXY_COMMAND"
          "SOCKS_SERVER"
        ];
      extraNativeBuildInputs = [
        gcc
        gnumake
        pkg-config
        python3
      ];
      extraEnv = ''
        export ELECTRON_SKIP_BINARY_DOWNLOAD=1
        export PLAYWRIGHT_SKIP_BROWSER_DOWNLOAD=1
        export npm_config_build_from_source=true
      '';
    };

    runtimeNodeModules = common.mkNodeModules {
      inherit (finalAttrs) pname version src;
      outputHash = "sha256-q1xo2GiU3Ct4Sq5+qGsfXMI0ei1c5AXkdq0GaBWr1PI=";
      installFlags = [
        "--production"
      ];
      filters = [
        "."
        "./apps/desktop"
        "./apps/server"
        "./apps/web"
        "./packages/client-runtime"
        "./packages/contracts"
        "./packages/effect-acp"
        "./packages/effect-codex-app-server"
        "./packages/shared"
      ];
      impureEnvVars =
        lib.fetchers.proxyImpureEnvVars
        ++ [
          "GIT_PROXY_COMMAND"
          "SOCKS_SERVER"
        ];
      extraNativeBuildInputs = [
        gcc
        gnumake
        pkg-config
        python3
      ];
      extraEnv = ''
        export ELECTRON_SKIP_BINARY_DOWNLOAD=1
        export PLAYWRIGHT_SKIP_BROWSER_DOWNLOAD=1
        export npm_config_build_from_source=true
      '';
    };

    nativeBuildInputs = [
      asar
      bun
      gcc
      gnumake
      makeWrapper
      node-gyp
      nodejs
      pkg-config
      python3
      writableTmpDirAsHomeHook
    ];

    env = {
      ELECTRON_SKIP_BINARY_DOWNLOAD = "1";
      PLAYWRIGHT_SKIP_BROWSER_DOWNLOAD = "1";
      npm_config_build_from_source = "true";
      npm_config_nodedir = "${nodejs}";
    };

    configurePhase = common.mkNodePtyConfigurePhase {
      nodeModules = finalAttrs.nodeModules;
      chmodBins = true;
    };

    buildPhase = ''
      runHook preBuild

      export HOME="$TMPDIR"
      export BUN_INSTALL_CACHE_DIR="$(mktemp -d)"

      bun run build:desktop
      node ${./build-nix-desktop-package.mjs} --output-dir packaged-app
      cp -R ${finalAttrs.runtimeNodeModules} packaged-app/node_modules
      chmod -R u+rwX packaged-app/node_modules
      rm -rf packaged-app/node_modules/node-pty
      cp -R node_modules/node-pty packaged-app/node_modules/
      patchShebangs packaged-app/node_modules
      find packaged-app/node_modules -xtype l -delete
      rm -rf packaged-app/node_modules/electron
      rm -f packaged-app/node_modules/.bin/electron
      asar pack --unpack='{*.node}' packaged-app packaged-app.asar

      runHook postBuild
    '';

    installPhase = ''
      runHook preInstall

      install -d "$out/share/${pname}/resources"
      install -Dm644 packaged-app.asar "$out/share/${pname}/resources/app.asar"
      if [ -d packaged-app.asar.unpacked ]; then
        cp -R packaged-app.asar.unpacked "$out/share/${pname}/resources/"
      fi

      install -Dm644 apps/desktop/resources/icon.png \
        "$out/share/icons/hicolor/512x512/apps/t3code.png"

      makeWrapper ${lib.getExe electron_40} "$out/bin/t3code" \
        --set T3CODE_DISABLE_AUTO_UPDATE 1 \
        --set-default ELECTRON_FORCE_IS_PACKAGED 1 \
        --set-default ELECTRON_IS_DEV 0 \
        --prefix PATH : ${lib.makeBinPath [
        git
        xdg-utils
      ]} \
        --add-flags "$out/share/${pname}/resources/app.asar"

      export out
      substituteAll ${./t3code.desktop.in} t3code.desktop
      install -Dm644 t3code.desktop "$out/share/applications/t3code.desktop"

      runHook postInstall
    '';

    meta = {
      description = "T3 Code desktop app";
      homepage = "https://github.com/pingdotgg/t3code";
      license = lib.licenses.mit;
      mainProgram = "t3code";
      platforms = ["x86_64-linux"];
      sourceProvenance = with lib.sourceTypes; [fromSource];
    };
  });
  withAgentPath = withCodex || withClaudeCode || withOpencode;
  agentPath = lib.makeBinPath (
    lib.optionals withCodex [codex]
    ++ lib.optionals withClaudeCode [claudeCode]
    ++ lib.optionals withOpencode [opencode]
  );
in
  assert lib.assertMsg (!withCodex || codex != null) "withCodex requires a codex package";
  assert lib.assertMsg (!withClaudeCode || claudeCode != null) "withClaudeCode requires a claudeCode package";
  assert lib.assertMsg (!withOpencode || opencode != null) "withOpencode requires an opencode package";
    if withAgentPath
    then
      symlinkJoin {
        inherit pname version;
        name = "${pname}-${version}";
        paths = [basePackage];
        nativeBuildInputs = [makeWrapper];
        postBuild = ''
          wrapProgram "$out/bin/t3code" \
            --prefix PATH : "${agentPath}"

          rm -f "$out/share/applications/t3code.desktop"
          install -Dm644 ${basePackage}/share/applications/t3code.desktop \
            "$out/share/applications/t3code.desktop"
          substituteInPlace "$out/share/applications/t3code.desktop" \
            --replace-fail "${basePackage}/bin/t3code" "$out/bin/t3code"
        '';
        meta = basePackage.meta;
      }
    else basePackage