{config, ...}: {
  programs.wl-kbptr = {
    enable = true;
    settings = with config.lib.stylix.colors.withHashtag; rec {
      general.cancellation_status_code = 1;
      mode_floating = {
        source = "detect";
        label_color = base05;
        label_select_color = base0A;
        unselectable_bg_color = "#2222";
        selectable_bg_color = base01 + "66";
        selectable_border_color = base01;
        label_font_family = config.stylix.fonts.sansSerif.name;
        label_font_size = "12 50% 100";
        label_symbols = "abcdefghijklmnopqrstuvwxyz";
      };
      mode_tile = {
        label_font_size = "8 50% 100";
        inherit
          (mode_floating)
          label_color
          label_select_color
          unselectable_bg_color
          selectable_bg_color
          selectable_border_color
          label_font_family
          label_symbols
          ;
      };
      mode_bisect = {
        inherit (mode_floating) label_color unselectable_bg_color label_font_family;
        label_font_size = 20;
        label_padding = "12";
        pointer_size = 24;
        pointer_color = base08;
        even_area_bg_color = base0C + "aa";
        even_area_border_color = base0C;
        odd_area_bg_color = base0D + "aa";
        odd_area_border_color = base0D;
        history_border_color = base01;
      };
      mode_split = {
        inherit (mode_bisect) pointer_size pointer_color history_border_color;
        bg_color = mode_floating.unselectable_bg_color;
        area_bg_color = mode_floating.selectable_bg_color;
        vertical_color = base09;
        horizontal_color = mode_bisect.odd_area_border_color;
      };
    };
  };
}