refactor modules/desktop

Signed-off-by: unexplrd <unexplrd@linerds.us>

modules/nixos/desktop/common/default.nix

@@ -0,0 +1,16 @@
+{config, ...}: {
+  imports = [
+    ./gnome-keyring.nix
+    ./greeter.nix
+    ./pam-rtprio.nix
+    ./pipewire.nix
+  ];
+  fonts.fontDir.enable = true;
+  security = {
+    pam = {
+      services.greetd.enableGnomeKeyring = config.services.greetd.enable && config.services.gnome.gnome-keyring.enable;
+    };
+  };
+  services.udisks2.enable = true;
+  programs.dconf.enable = true;
+}

modules/nixos/desktop/common/gnome-keyring.nix

@@ -0,0 +1,25 @@
+{
+  lib,
+  pkgs,
+  config,
+  ...
+}: let
+  inherit (lib) mkEnableOption mkIf;
+  cfg = config.module.desktop.gnome-keyring;
+in {
+  options = {
+    module.desktop.gnome-keyring.enable = mkEnableOption "enable gnome keyring";
+  };
+
+  config = mkIf cfg.enable {
+    environment.systemPackages = with pkgs; [
+      gcr_4
+      libsecret
+    ];
+    # programs.seahorse.enable = true;
+    services.gnome.gnome-keyring.enable = true;
+    xdg.portal.config.common = {
+      "org.freedesktop.impl.portal.Secret" = ["gnome-keyring"];
+    };
+  };
+}

modules/nixos/desktop/common/greeter.nix

@@ -0,0 +1,48 @@
+{
+  lib,
+  pkgs,
+  config,
+  ...
+}: let
+  inherit (lib) mkOption mkIf getExe types mkMerge;
+  cfg = config.module.desktop;
+in {
+  options = {
+    module.desktop.displayManager = mkOption {
+      default = "greetd";
+      type = types.enum [
+        "cosmic"
+        "gdm"
+        "greetd"
+        "sddm"
+      ];
+    };
+  };
+
+  config = mkMerge [
+    (mkIf (cfg.displayManager == "cosmic") {
+      services.displayManager.cosmic-greeter.enable = true;
+    })
+    (mkIf (cfg.displayManager == "gdm") {
+      services.xserver.displayManager.gdm.enable = true;
+    })
+    (mkIf (cfg.displayManager == "greetd") {
+      programs.regreet.enable = true;
+      services.greetd = {
+        enable = true;
+        vt = 1;
+        settings = {
+          default_session = {
+            command = "${getExe pkgs.cage} -s -m last -- ${getExe pkgs.greetd.regreet}";
+          };
+        };
+      };
+    })
+    (mkIf (cfg.displayManager == "sddm") {
+      services.displayManager.sddm = {
+        enable = true;
+        wayland.enable = true;
+      };
+    })
+  ];
+}

modules/nixos/desktop/common/pam-rtprio.nix

@@ -0,0 +1,10 @@
+{
+  security.pam.loginLimits = [
+    {
+      domain = "@users";
+      item = "rtprio";
+      type = "-";
+      value = -1;
+    }
+  ];
+}