add dotfiles

fish/completions/bun.fish

@@ -0,0 +1,186 @@
+# This is terribly complicated
+# It's because:
+# 1. bun run has to have dynamic completions
+# 2. there are global options
+# 3. bun {install add remove} gets special options
+# 4. I don't know how to write fish completions well
+# Contributions very welcome!!
+
+function __fish__get_bun_bins
+	string split ' ' (bun getcompletes b)
+end
+
+function __fish__get_bun_scripts
+	set -lx SHELL bash
+	set -lx MAX_DESCRIPTION_LEN 40
+	string trim (string split '\n' (string split '\t' (bun getcompletes z)))
+end
+
+function __fish__get_bun_packages
+	if test (commandline -ct) != ""
+		set -lx SHELL fish
+		string split ' ' (bun getcompletes a (commandline -ct))
+	end
+end
+
+function __history_completions
+	set -l tokens (commandline --current-process --tokenize)
+	history --prefix (commandline) | string replace -r \^$tokens[1]\\s\* "" | string replace -r \^$tokens[2]\\s\* "" | string split ' '
+end
+
+function __fish__get_bun_bun_js_files
+	string split ' ' (bun getcompletes j)
+end
+
+set -l bun_install_boolean_flags yarn production optional development no-save dry-run force no-cache silent verbose global
+set -l bun_install_boolean_flags_descriptions "Write a yarn.lock file (yarn v1)" "Don't install devDependencies" "Add dependency to optionalDependencies" "Add dependency to devDependencies" "Don't update package.json or save a lockfile" "Don't install anything" "Always request the latest versions from the registry & reinstall all dependencies" "Ignore manifest cache entirely" "Don't output anything" "Excessively verbose logging" "Use global folder"
+
+set -l bun_builtin_cmds_without_run dev create help bun upgrade discord install remove add init pm x
+set -l bun_builtin_cmds_accepting_flags create help bun upgrade discord run init link unlink pm x
+
+function __bun_complete_bins_scripts --inherit-variable bun_builtin_cmds_without_run -d "Emit bun completions for bins and scripts"
+    # Do nothing if we already have a builtin subcommand,
+    # or any subcommand other than "run".
+    if __fish_seen_subcommand_from $bun_builtin_cmds_without_run
+    or not __fish_use_subcommand && not __fish_seen_subcommand_from run
+        return
+    end
+    # Do we already have a bin or script subcommand?
+    set -l bins (__fish__get_bun_bins)
+    if __fish_seen_subcommand_from $bins
+        return
+    end
+    # Scripts have descriptions appended with a tab separator.
+    # Strip off descriptions for the purposes of subcommand testing.
+    set -l scripts (__fish__get_bun_scripts)
+    if __fish_seen_subcommand_from (string split \t -f 1 -- $scripts)
+        return
+    end
+    # Emit scripts.
+    for script in $scripts
+        echo $script
+    end
+    # Emit binaries and JS files (but only if we're doing `bun run`).
+    if __fish_seen_subcommand_from run
+        for bin in $bins
+            echo "$bin"\t"package bin"
+        end
+        for file in (__fish__get_bun_bun_js_files)
+            echo "$file"\t"Bun.js"
+        end
+    end
+end
+
+
+# Clear existing completions
+complete -e -c bun
+
+# Dynamically emit scripts and binaries
+complete -c bun -f -a "(__bun_complete_bins_scripts)"
+
+# Complete flags if we have no subcommand or a flag-friendly one.
+set -l flag_applies "__fish_use_subcommand; or __fish_seen_subcommand_from $bun_builtin_cmds_accepting_flags"
+complete -c bun \
+	-n $flag_applies --no-files -s 'u' -l 'origin' -r -d 'Server URL. Rewrites import paths'
+complete -c bun \
+	-n $flag_applies --no-files  -s 'p' -l 'port' -r -d 'Port number to start server from'
+complete -c bun \
+	-n $flag_applies --no-files  -s 'd' -l 'define' -r -d 'Substitute K:V while parsing, e.g. --define process.env.NODE_ENV:\"development\"'
+complete -c bun \
+	-n $flag_applies --no-files  -s 'e' -l 'external' -r -d 'Exclude module from transpilation (can use * wildcards). ex: -e react'
+complete -c bun \
+	-n $flag_applies --no-files -l 'use' -r -d 'Use a framework (ex: next)'
+complete -c bun \
+	-n $flag_applies --no-files -l 'hot' -r -d 'Enable hot reloading in Bun\'s JavaScript runtime'
+
+# Complete dev and create as first subcommand.
+complete -c bun \
+	-n "__fish_use_subcommand" -a 'dev' -d 'Start dev server'
+complete -c bun \
+	-n "__fish_use_subcommand" -a 'create' -f -d 'Create a new project from a template'
+
+# Complete "next" and "react" if we've seen "create".
+complete -c bun \
+	-n "__fish_seen_subcommand_from create" -a 'next' -d 'new Next.js project'
+
+complete -c bun \
+	-n "__fish_seen_subcommand_from create" -a 'react' -d 'new React project'
+
+# Complete "upgrade" as first subcommand.
+complete -c bun \
+	-n "__fish_use_subcommand" -a 'upgrade' -d 'Upgrade bun to the latest version' -x
+# Complete "-h/--help" unconditionally.
+complete -c bun \
+	-s "h" -l "help" -d 'See all commands and flags' -x
+
+# Complete "-v/--version" if we have no subcommand.
+complete -c bun \
+	-n "not __fish_use_subcommand" -l "version" -s "v" -d 'Bun\'s version' -x
+
+# Complete additional subcommands.
+complete -c bun \
+	-n "__fish_use_subcommand" -a 'discord' -d 'Open bun\'s Discord server' -x
+
+
+complete -c bun \
+	-n "__fish_use_subcommand" -a 'bun' -d 'Generate a new bundle'
+
+
+complete -c bun \
+	-n "__fish_seen_subcommand_from bun" -F -d 'Bundle this'
+
+complete -c bun \
+	-n "__fish_seen_subcommand_from create; and __fish_seen_subcommand_from react next" -F -d "Create in directory"
+
+
+complete -c bun \
+	-n "__fish_use_subcommand" -a 'init' -F -d 'Start an empty Bun project'
+
+complete -c bun \
+	-n "__fish_use_subcommand" -a 'install' -f -d 'Install packages from package.json'
+
+complete -c bun \
+	-n "__fish_use_subcommand" -a 'add' -F -d 'Add a package to package.json'
+
+complete -c bun \
+	-n "__fish_use_subcommand" -a 'remove' -F -d 'Remove a package from package.json'
+
+
+for i in (seq (count $bun_install_boolean_flags))
+	complete -c bun \
+		-n "__fish_seen_subcommand_from install add remove" -l "$bun_install_boolean_flags[$i]" -d "$bun_install_boolean_flags_descriptions[$i]"
+end
+
+complete -c bun \
+	-n "__fish_seen_subcommand_from install add remove" -l 'cwd' -d 'Change working directory'
+
+complete -c bun \
+	-n "__fish_seen_subcommand_from install add remove" -l 'cache-dir' -d 'Choose a cache directory (default: $HOME/.bun/install/cache)'
+
+complete -c bun \
+	-n "__fish_seen_subcommand_from add" -d 'Popular' -a '(__fish__get_bun_packages)'
+
+complete -c bun \
+	-n "__fish_seen_subcommand_from add" -d 'History' -a '(__history_completions)'
+
+complete -c bun \
+	-n "__fish_seen_subcommand_from pm; and not __fish_seen_subcommand_from (__fish__get_bun_bins) (__fish__get_bun_scripts) cache;" -a 'bin ls cache hash hash-print hash-string' -f
+
+complete -c bun \
+	-n "__fish_seen_subcommand_from pm; and __fish_seen_subcommand_from cache; and not __fish_seen_subcommand_from (__fish__get_bun_bins) (__fish__get_bun_scripts);" -a 'rm' -f
+
+# Add built-in subcommands with descriptions.
+complete -c bun -n "__fish_use_subcommand" -a "create" -f -d "Create a new project from a template"
+complete -c bun -n "__fish_use_subcommand" -a "build bun" --require-parameter -F -d "Transpile and bundle one or more files"
+complete -c bun -n "__fish_use_subcommand" -a "upgrade" -d "Upgrade Bun"
+complete -c bun -n "__fish_use_subcommand" -a "run" -d "Run a script or package binary"
+complete -c bun -n "__fish_use_subcommand" -a "install" -d "Install dependencies from package.json" -f
+complete -c bun -n "__fish_use_subcommand" -a "remove" -d "Remove a dependency from package.json" -f
+complete -c bun -n "__fish_use_subcommand" -a "add" -d "Add a dependency to package.json" -f
+complete -c bun -n "__fish_use_subcommand" -a "init" -d "Initialize a Bun project in this directory" -f
+complete -c bun -n "__fish_use_subcommand" -a "link" -d "Register or link a local npm package" -f
+complete -c bun -n "__fish_use_subcommand" -a "unlink" -d "Unregister a local npm package" -f
+complete -c bun -n "__fish_use_subcommand" -a "pm" -d "Additional package management utilities" -f
+complete -c bun -n "__fish_use_subcommand" -a "x" -d "Execute a package binary, installing if needed" -f
+complete -c bun -n "__fish_use_subcommand" -a "outdated" -d "Display the latest versions of outdated dependencies" -f
+complete -c bun -n "__fish_use_subcommand" -a "publish" -d "Publish your package from local to npm" -f

fish/completions/sdk.fish

@@ -0,0 +1,243 @@
+# Defines autocompletion for SDKMAN!
+
+# Copyright (c) 2018-2023 Raphael Reitzig
+# MIT License (MIT)
+# https://github.com/reitzig/sdkman-for-fish
+
+# Guard: SDKMAN! needs to be installed
+if not test -f "$SDKMAN_DIR/bin/sdkman-init.sh"
+    exit 0
+end
+
+# # # # # #
+# Completion trigger predicates
+# # # # # #
+
+# Test if there is no command
+function __fish_sdkman_no_command
+    set cmd (commandline -opc)
+
+    if [ (count $cmd) -eq 1 ]
+        return 0
+    end
+    return 1
+end
+
+# Test if the main command matches one of the parameters
+function __fish_sdkman_using_command
+    set cmd (commandline -opc)
+
+    if [ (count $cmd) -eq 2 ]
+        if contains $cmd[2] $argv
+            return 0
+        end
+    end
+    return 1
+end
+
+function __fish_sdkman_specifying_candidate
+    set cmd (commandline -opc)
+
+    if [ (count $cmd) -eq 3 ] # currently, sdk does not support multiple versions
+        if contains $cmd[2] $argv
+            return 0
+        end
+    end
+    return 1
+end
+
+function __fish_sdkman_command_has_enough_parameters
+    set cmd (commandline -opc)
+
+    if [ (count $cmd) -ge (math $argv[1] + 2) ]; and contains $cmd[2] $argv[2..-1]
+        return 0
+    end
+    return 1
+end
+
+# # # # # #
+# Data collectors
+# # # # # #
+
+function __fish_sdkman_candidates
+    cat "$SDKMAN_DIR"/var/candidates | string replace -a -r ',' '\n'
+end
+
+function __fish_sdkman_candidates_with_versions
+    set regexpHome (string replace -a '/' '\\/' "$HOME/")
+
+    find "$SDKMAN_DIR"/candidates/ -mindepth 2 -maxdepth 2 -name '*current' \
+    | awk -F '/' '{ print $(NF-1) }' \
+    | sort -u
+end
+
+function __fish_sdkman_installed_versions
+    set cmd (commandline -opc)
+    if [ -d "$SDKMAN_DIR"/candidates/$cmd[3]/current ]
+        ls -v1 "$SDKMAN_DIR"/candidates/$cmd[3] | grep -v current
+    end
+end
+
+# # # # # #
+# Completion specification
+# # # # # #
+
+# install
+complete -c sdk -f -n '__fish_sdkman_no_command' \
+    -a 'i install' \
+    -d 'Install new version'
+complete -c sdk -f -n '__fish_sdkman_using_command i install' \
+        -a "(__fish_sdkman_candidates)"
+# TODO complete available versions --> issue #4
+complete -c sdk -f -n '__fish_sdkman_specifying_candidate i install' \
+            -a 'a.b.c' \
+            -d "version list unavailable"
+complete -c sdk -f -n '__fish_sdkman_specifying_candidate i install' \
+            -a 'x.y.z' \
+            -d "Specify path to install custom version."
+# Implicit: complete files as fourth parameter
+complete -c sdk -f -n '__fish_sdkman_command_has_enough_parameters 3 i install'
+                    # block
+
+# uninstall
+complete -c sdk -f -n '__fish_sdkman_no_command' \
+    -a 'rm uninstall' -d 'Uninstall version'
+complete -c sdk -f -n '__fish_sdkman_using_command rm uninstall' \
+        -a "(__fish_sdkman_candidates_with_versions)"
+complete -c sdk -f -n '__fish_sdkman_specifying_candidate rm uninstall' \
+            -a "(__fish_sdkman_installed_versions)"
+complete -c sdk -f -n '__fish_sdkman_command_has_enough_parameters 2 rm uninstall'
+                # block
+
+# list
+complete -c sdk -f -n '__fish_sdkman_no_command' \
+    -a 'ls list' \
+    -d 'List versions'
+complete -c sdk -f -n '__fish_sdkman_using_command ls list' \
+        -a "(__fish_sdkman_candidates)"
+complete -c sdk -f -n '__fish_sdkman_command_has_enough_parameters 1 ls list'
+            # block
+
+# use
+complete -c sdk -f -n '__fish_sdkman_no_command' \
+    -a 'u use' \
+    -d 'Use specific version'
+complete -c sdk -f -n '__fish_sdkman_using_command u use' \
+        -a "(__fish_sdkman_candidates_with_versions)"
+complete -c sdk -f -n '__fish_sdkman_specifying_candidate u use' \
+            -a "(__fish_sdkman_installed_versions)"
+complete -c sdk -f -n '__fish_sdkman_command_has_enough_parameters 2 u use'
+                # block
+
+# default
+complete -c sdk -f -n '__fish_sdkman_no_command' \
+    -a 'd default' \
+    -d 'Set default version'
+complete -c sdk -f -n '__fish_sdkman_using_command d default' \
+        -a "(__fish_sdkman_candidates_with_versions)"
+complete -c sdk -f -n '__fish_sdkman_specifying_candidate d default' \
+            -a "(__fish_sdkman_installed_versions)"
+complete -c sdk -f -n '__fish_sdkman_command_has_enough_parameters 2 d default'
+                # block
+
+# current
+complete -c sdk -f -n '__fish_sdkman_no_command' \
+    -a 'c current' \
+    -d 'Display current version'
+complete -c sdk -f -n '__fish_sdkman_using_command c current' \
+        -a "(__fish_sdkman_candidates)"
+complete -c sdk -f -n '__fish_sdkman_command_has_enough_parameters 1 c current'
+            # block
+
+# upgrade
+complete -c sdk -f -n '__fish_sdkman_no_command' \
+    -a 'ug upgrade' \
+    -d 'Display what is outdated'
+complete -c sdk -f -n '__fish_sdkman_using_command ug upgrade' \
+        -a "(__fish_sdkman_candidates_with_versions)"
+complete -c sdk -f -n '__fish_sdkman_command_has_enough_parameters 1 ug upgrade'
+            # block
+
+# version
+complete -c sdk -f -n '__fish_sdkman_no_command' \
+    -a 'v version' \
+    -d 'Display version'
+complete -c sdk -f -n '__fish_sdkman_command_has_enough_parameters 0 v version'
+        # block
+
+# help
+complete -c sdk -f -n '__fish_sdkman_no_command' \
+    -a 'help' \
+    -d 'Display help message'
+complete -c sdk -f -n '__fish_sdkman_command_has_enough_parameters 0 h help'
+        # block
+
+# offline
+complete -c sdk -f -n '__fish_sdkman_no_command' \
+    -a 'offline' \
+    -d 'Set offline status'
+complete -c sdk -f -n '__fish_sdkman_using_command offline' \
+        -a 'enable' \
+        -d 'Make sdk work while offline'
+complete -c sdk -f -n '__fish_sdkman_using_command offline' \
+        -a 'disable' \
+        -d 'Turn on all features'
+complete -c sdk -f -n '__fish_sdkman_command_has_enough_parameters 1 offline'
+            # block
+
+# selfupdate
+complete -c sdk -f -n '__fish_sdkman_no_command' \
+    -a 'selfupdate' \
+    -d 'Update sdk'
+complete -c sdk -f -n '__fish_sdkman_using_command selfupdate' \
+        -a 'force' \
+        -d 'Force re-install of current version'
+complete -c sdk -f -n '__fish_sdkman_command_has_enough_parameters 1 selfupdate'
+            # block
+
+# update
+complete -c sdk -f -n '__fish_sdkman_no_command' \
+    -a 'update' \
+    -d 'Reload the candidate list'
+complete -c sdk -f -n '__fish_sdkman_command_has_enough_parameters 0 update'
+        # block
+
+# flush
+complete -c sdk -f -n '__fish_sdkman_no_command' \
+    -a 'flush' \
+    -d 'Clear out archives and temporary storage folders'
+complete -c sdk -f -n '__fish_sdkman_using_command flush' \
+        -a 'temp' \
+        -d 'Clear out staging work folder'
+complete -c sdk -f -n '__fish_sdkman_using_command flush' \
+        -a 'version' \
+        -d 'Flush version file'
+complete -c sdk -f -n '__fish_sdkman_command_has_enough_parameters 1 flush'
+            # block
+
+# env
+complete -c sdk -f -n '__fish_sdkman_no_command' \
+    -a 'e env' \
+    -d 'Load environment from .sdkmanrc file'
+complete -c sdk -f -n '__fish_sdkman_using_command e env' \
+        -a 'init' \
+        -d 'Initialize .sdkmanrc file'
+complete -c sdk -f -n '__fish_sdkman_using_command e env' \
+        -a 'install' \
+        -d 'Install all candidate versions listed in .sdkmanrc'
+complete -c sdk -f -n '__fish_sdkman_using_command e env' \
+        -a 'clear' \
+        -d 'Unload currently loaded environment'
+complete -c sdk -f -n '__fish_sdkman_command_has_enough_parameters 1 e env'
+            # block
+
+# home
+complete -c sdk -f -n '__fish_sdkman_no_command' \
+    -a 'h home' \
+    -d 'Show installation folder of given candidate'
+complete -c sdk -f -n '__fish_sdkman_using_command h home' \
+        -a "(__fish_sdkman_candidates_with_versions)"
+complete -c sdk -f -n '__fish_sdkman_specifying_candidate h home' \
+            -a "(__fish_sdkman_installed_versions)"
+complete -c sdk -f -n '__fish_sdkman_command_has_enough_parameters 2 h home'
+                # block

fish/completions/uv.fish

@@ -0,0 +1 @@
+uv generate-shell-completion fish | source

fish/conf.d/fish_frozen_key_bindings.fish

@@ -0,0 +1,14 @@
+# This file was created by fish when upgrading to version 4.3, to migrate
+# the 'fish_key_bindings' variable from its old default scope (universal)
+# to its new default scope (global).  We recommend you delete this file
+# and configure key bindings in ~/.config/fish/config.fish if needed.
+
+# set --global fish_key_bindings fish_default_key_bindings
+
+# Prior to version 4.3, fish shipped an event handler that runs
+# `set --universal fish_key_bindings fish_default_key_bindings`
+# whenever the fish_key_bindings variable is erased.
+# This means that as long as any fish < 4.3 is still running on this system,
+# we cannot complete the migration.
+# As a workaround, erase the universal variable at every shell startup.
+set --erase --universal fish_key_bindings

fish/conf.d/fish_frozen_theme.fish

@@ -0,0 +1,37 @@
+# This file was created by fish when upgrading to version 4.3, to migrate
+# theme variables from universal to global scope.
+# Don't edit this file, as it will be written by the web-config tool (`fish_config`).
+# To customize your theme, delete this file and see
+#     help interactive#syntax-highlighting
+# or
+#     man fish-interactive | less +/^SYNTAX.HIGHLIGHTING
+# for appropriate commands to add to ~/.config/fish/config.fish instead.
+# See also the release notes for fish 4.3.0 (run `help relnotes`).
+
+set --global fish_color_autosuggestion 555 brblack
+set --global fish_color_cancel -r
+set --global fish_color_command blue
+set --global fish_color_comment red
+set --global fish_color_cwd green
+set --global fish_color_cwd_root red
+set --global fish_color_end green
+set --global fish_color_error brred
+set --global fish_color_escape brcyan
+set --global fish_color_history_current --bold
+set --global fish_color_host normal
+set --global fish_color_host_remote yellow
+set --global fish_color_normal normal
+set --global fish_color_operator brcyan
+set --global fish_color_param cyan
+set --global fish_color_quote yellow
+set --global fish_color_redirection cyan --bold
+set --global fish_color_search_match white --background=brblack
+set --global fish_color_selection white --bold --background=brblack
+set --global fish_color_status red
+set --global fish_color_user brgreen
+set --global fish_color_valid_path --underline
+set --global fish_pager_color_completion normal
+set --global fish_pager_color_description B3A06D yellow -i
+set --global fish_pager_color_prefix normal --bold --underline
+set --global fish_pager_color_progress brwhite --background=cyan
+set --global fish_pager_color_selected_background -r

fish/conf.d/sdk.fish

@@ -0,0 +1,111 @@
+#!/usr/bin/fish
+
+# Makes command and binaries from SDKMAN! available in fish.
+# Delegates to bash for the `sdk` command.
+
+# Copyright (c) 2018-2023 Raphael Reitzig
+# MIT License (MIT)
+# https://github.com/reitzig/sdkman-for-fish
+
+# Account for custom install locations
+if set -q __sdkman_custom_dir
+    set -gx SDKMAN_DIR "$__sdkman_custom_dir"
+end
+# Guard: SDKMAN! needs to be installed
+if set -q SDKMAN_DIR; and not test -f "$SDKMAN_DIR/bin/sdkman-init.sh"
+    echo "WARNING: SDKMAN! installation path set to $SDKMAN_DIR, but no installation found there"
+    exit 0
+end
+
+# Unless overridden, use the default location:
+if not set -q SDKMAN_DIR
+    set -gx SDKMAN_DIR "$HOME/.sdkman"
+end
+
+set __fish_sdkman_init "$SDKMAN_DIR/bin/sdkman-init.sh"
+
+# Guard: SDKMAN! needs to be installed
+if not test -f "$__fish_sdkman_init"
+    exit 0
+end
+
+# Copied from https://github.com/jorgebucaran/fisher/blob/main/functions/fisher.fish to be consistent:
+set --query fisher_path || set --local fisher_path $__fish_config_dir
+set __fish_sdkman_noexport_init "$fisher_path/functions/__sdkman-noexport-init.sh"
+
+# Hack for issue #19:
+# Create version of sdkman-init that doesn't export any environment variables.
+# Refresh if sdkman-init changed.
+if  begin       not test -f "$__fish_sdkman_noexport_init";
+          or    env test "$__fish_sdkman_init" -nt "$__fish_sdkman_noexport_init"
+    end
+    mkdir -p (dirname $__fish_sdkman_noexport_init)
+    sed -E -e 's/^(\s*).*(export|to_path).*$/\1:/g' "$__fish_sdkman_init" \
+        > "$__fish_sdkman_noexport_init"
+end
+
+# Runs the given command in bash, capturing some side effects
+# and repeating them on the current fish shell.
+# Returns the same status code as the given command.
+function __fish_sdkman_run_in_bash
+    # We need to leave stdin and stdout of sdk free for user interaction.
+    # So, pipe relevant environment variables (which might have changed)
+    # through a file.
+    # But since now getting the exit code of sdk itself is a hassle,
+    # pipe it as well.
+    #
+    # TODO: Can somebody get this to work without the overhead of a file?
+    set pipe (mktemp)
+    bash -c "$argv[1];
+             echo -e \"\$?\" > $pipe;
+             env | grep -e '^SDKMAN_\|^PATH' >> $pipe;
+             env | grep -i -E \"^(`echo \${SDKMAN_CANDIDATES_CSV} | sed 's/,/|/g'`)_HOME\" >> $pipe;
+             echo \"SDKMAN_OFFLINE_MODE=\${SDKMAN_OFFLINE_MODE}\" >> $pipe;
+             echo \"SDKMAN_ENV=\${SDKMAN_ENV}\" >> $pipe" # it's not an environment variable!
+    set bashDump (cat $pipe; rm $pipe)
+
+    set sdkStatus $bashDump[1]
+    set bashEnv $bashDump[2..-1]
+
+    # If SDKMAN! succeeded, copy relevant environment variables
+    # to the current shell (they might have changed)
+    if [ $sdkStatus = 0 ]
+        for line in $bashEnv
+            set parts (string split "=" $line)
+            set var $parts[1]
+            set value (string join "=" $parts[2..-1])
+
+            switch "$var"
+            case "PATH"
+                # Special treatment: need fish list instead
+                # of colon-separated list.
+                set value (string split : "$value")
+            end
+
+            if test -n value
+                set -gx $var $value
+                # Note: This makes SDKMAN_{OFFLINE_MODE,ENV} environment variables.
+                #       That gives it the behaviour we _want_!
+            end
+        end
+    end
+
+    return $sdkStatus
+end
+
+# If this is a subshell of a(n initialized) fish owned by the same user,
+# no initialization necessary.
+# Otherwise:
+if not set -q SDKMAN_CANDIDATES_DIR; or test (ls -ld "$SDKMAN_CANDIDATES_DIR" | awk '{print $3}') != (whoami)
+    __fish_sdkman_run_in_bash "source $__fish_sdkman_init"
+end
+
+# Set up auto_env
+if grep -q "^sdkman_auto_env=true" "$SDKMAN_DIR/etc/config"
+    function __fish_sdkman_autoenv --on-variable PWD
+        # Run the (modified) init script, which performs the checks and calls for us!
+        __fish_sdkman_run_in_bash "source \"$__fish_sdkman_noexport_init\""
+
+        set -x SDKMAN_OLD_PWD "$PWD" # needed by the Bash implementation
+    end
+end

fish/config.fish

@@ -0,0 +1,39 @@
+if status is-interactive
+    # Commands to run in interactive sessions can go here
+    zoxide init fish | source
+    fzf --fish | source
+
+    set -gx EDITOR nvim
+    set -gx QT_QPA_PLATFORM wayland
+    # set -gx GRAALVM_HOME /home/dxrkness/.sdkman/candidates/java/25-graal/
+    set -gx JAVA_HOME /home/dxrkness/.sdkman/candidates/java/current/
+    set -gx BUN_INSTALL $HOME/.bun
+    set -gx SDKMAN_DIR $HOME/.sdkman
+    set -gx RUSTBIN $HOME/.cargo/bin
+    set -gx RUSTUP_BIN $HOME/.rustup/toolchains/stable-x86_64-unknown-linux-gnu/bin
+    set -gx GOBIN $HOME/go/bin
+    set -gx LOCAL_BIN /home/dxrkness/.local/bin
+    set -gx PATH $PATH $GOBIN $JAVA_HOME/bin $BUN_INSTALL/bin $RUSTBIN $RUSTUP_BIN $LOCAL_BIN
+    set -gx TESTCONTAINERS_RYUK_DISABLED true
+    set -gx TESTCONTAINERS_DOCKER_SOCKET_OVERRIDE /var/run/docker.sock
+    set -gx CC clang
+    set -gx GTK_IM_MODULE ibus
+    set -gx QT_IM_MODULE ibus
+    set -gx XMODIFIERS @im=ibus
+    set -gx MANPAGER "nvim +Man!"
+    set -gx PROTON_ENABLE_WAYLAND 1
+
+    alias sudo doas
+    abbr ls "eza"
+    alias cp "uu-cp -v -g"
+    alias rm "uu-rm -v"
+    alias mv "uu-mv -v -g"
+    abbr cd z # zoxide
+    abbr find "fd"
+    abbr wlp wl-paste
+
+    alias jcu 'journalctl --user'
+    alias jc journalctl
+    alias scu 'systemctl --user'
+    alias sc systemctl
+end

fish/fish_plugins

@@ -0,0 +1 @@
+reitzig/sdkman-for-fish

fish/fish_variables

@@ -0,0 +1,7 @@
+# This file contains fish universal variable definitions.
+# VERSION: 3.0
+SETUVAR __fish_initialized:4300
+SETUVAR _fisher_plugins:reitzig/sdkman\x2dfor\x2dfish
+SETUVAR _fisher_reitzig_2F_sdkman_2D_for_2D_fish_files:\x7e/\x2econfig/fish/functions/sdk\x2efish\x1e\x7e/\x2econfig/fish/conf\x2ed/sdk\x2efish\x1e\x7e/\x2econfig/fish/completions/sdk\x2efish
+SETUVAR _fisher_upgraded_to_4_4:\x1d
+SETUVAR fish_user_paths:/usr/bin

fish/functions/__sdkman-noexport-init.sh

@@ -0,0 +1,175 @@
+#!/usr/bin/env bash
+
+#
+#   Copyright 2021 Marco Vermeulen
+#
+#   Licensed under the Apache License, Version 2.0 (the "License");
+#   you may not use this file except in compliance with the License.
+#   You may obtain a copy of the License at
+#
+#       http://www.apache.org/licenses/LICENSE-2.0
+#
+#   Unless required by applicable law or agreed to in writing, software
+#   distributed under the License is distributed on an "AS IS" BASIS,
+#   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+#   See the License for the specific language governing permissions and
+#   limitations under the License.
+#
+
+# set env vars if not set
+if [ -z "$SDKMAN_CANDIDATES_API" ]; then
+	:
+fi
+
+if [ -z "$SDKMAN_DIR" ]; then
+	:
+fi
+
+# Load the sdkman config if it exists.
+if [ -f "${SDKMAN_DIR}/etc/config" ]; then
+	source "${SDKMAN_DIR}/etc/config"
+fi
+
+# Read the platform file
+SDKMAN_PLATFORM="$(cat "${SDKMAN_DIR}/var/platform")"
+:
+
+# OS specific support (must be 'true' or 'false').
+cygwin=false
+darwin=false
+solaris=false
+freebsd=false
+SDKMAN_KERNEL="$(uname -s)"
+case "${SDKMAN_KERNEL}" in
+	CYGWIN*)
+		cygwin=true
+		;;
+	Darwin*)
+		darwin=true
+		;;
+	SunOS*)
+		solaris=true
+		;;
+	FreeBSD*)
+		freebsd=true
+esac
+
+# Determine shell
+zsh_shell=false
+bash_shell=false
+
+if [[ -n "$ZSH_VERSION" ]]; then
+	zsh_shell=true
+elif [[ -n "$BASH_VERSION" ]]; then
+	bash_shell=true
+fi
+
+# Source sdkman module scripts and extension files.
+#
+# Extension files are prefixed with 'sdkman-' and found in the ext/ folder.
+# Use this if extensions are written with the functional approach and want
+# to use functions in the main sdkman script. For more details, refer to
+# <https://github.com/sdkman/sdkman-extensions>.
+OLD_IFS="$IFS"
+IFS=$'\n'
+scripts=($(find "${SDKMAN_DIR}/src" "${SDKMAN_DIR}/ext" -type f -name 'sdkman-*.sh'))
+for f in "${scripts[@]}"; do
+	source "$f"
+done
+IFS="$OLD_IFS"
+unset OLD_IFS scripts f
+
+# Create upgrade delay file if it doesn't exist
+if [[ ! -f "${SDKMAN_DIR}/var/delay_upgrade" ]]; then
+	touch "${SDKMAN_DIR}/var/delay_upgrade"
+fi
+
+# set curl connect-timeout and max-time
+if [[ -z "$sdkman_curl_connect_timeout" ]]; then sdkman_curl_connect_timeout=7; fi
+if [[ -z "$sdkman_curl_max_time" ]]; then sdkman_curl_max_time=10; fi
+
+# set curl retry
+if [[ -z "${sdkman_curl_retry}" ]]; then sdkman_curl_retry=0; fi
+
+# set curl retry max time in seconds
+if [[ -z "${sdkman_curl_retry_max_time}" ]]; then sdkman_curl_retry_max_time=60; fi
+
+# set curl to continue downloading automatically
+if [[ -z "${sdkman_curl_continue}" ]]; then sdkman_curl_continue=true; fi
+
+# read list of candidates and set array
+SDKMAN_CANDIDATES_CACHE="${SDKMAN_DIR}/var/candidates"
+SDKMAN_CANDIDATES_CSV=$(<"$SDKMAN_CANDIDATES_CACHE")
+__sdkman_echo_debug "Setting candidates csv: $SDKMAN_CANDIDATES_CSV"
+if [[ "$zsh_shell" == 'true' ]]; then
+	SDKMAN_CANDIDATES=(${(s:,:)SDKMAN_CANDIDATES_CSV})
+else
+	IFS=',' read -a SDKMAN_CANDIDATES <<< "${SDKMAN_CANDIDATES_CSV}"
+fi
+
+:
+
+for candidate_name in "${SDKMAN_CANDIDATES[@]}"; do
+	candidate_dir="${SDKMAN_CANDIDATES_DIR}/${candidate_name}/current"
+	if [[ -h "$candidate_dir" || -d "${candidate_dir}" ]]; then
+		:
+		:
+	fi
+done
+unset candidate_name candidate_dir
+:
+
+# source completion scripts
+if [[ "$sdkman_auto_complete" == 'true' ]]; then
+	if [[ "$zsh_shell" == 'true' ]]; then
+		# initialize zsh completions (if not already done)
+		if ! (( $+functions[compdef] )) ; then
+			autoload -Uz compinit
+			if [[ $ZSH_DISABLE_COMPFIX == 'true' ]]; then
+				compinit -u -C
+			else
+				compinit
+			fi
+		fi
+		autoload -U bashcompinit
+		bashcompinit
+		source "${SDKMAN_DIR}/contrib/completion/bash/sdk"
+		__sdkman_echo_debug "ZSH completion script loaded..."
+	elif [[ "$bash_shell" == 'true' ]]; then
+		source "${SDKMAN_DIR}/contrib/completion/bash/sdk"
+		__sdkman_echo_debug "Bash completion script loaded..."
+	else
+		__sdkman_echo_debug "No completion scripts found for $SHELL"
+	fi
+fi
+
+if [[ "$sdkman_auto_env" == "true" ]]; then
+	if [[ "$zsh_shell" == "true" ]]; then
+		function sdkman_auto_env() {
+			if [[ -n $SDKMAN_ENV ]] && [[ ! $PWD =~ ^$SDKMAN_ENV ]]; then
+				sdk env clear
+			fi
+			if [[ -f .sdkmanrc ]]; then
+				sdk env
+			fi
+		}
+
+		chpwd_functions+=(sdkman_auto_env)
+	else
+		function sdkman_auto_env() {
+			if [[ -n $SDKMAN_ENV ]] && [[ ! $PWD =~ ^$SDKMAN_ENV ]]; then
+				sdk env clear
+			fi
+			if [[ "$SDKMAN_OLD_PWD" != "$PWD" ]] && [[ -f ".sdkmanrc" ]]; then
+				sdk env
+			fi
+
+			:
+		}
+		
+		trimmed_prompt_command="${PROMPT_COMMAND%"${PROMPT_COMMAND##*[![:space:]]}"}"
+		[[ -z "$trimmed_prompt_command" ]] && PROMPT_COMMAND="sdkman_auto_env" || PROMPT_COMMAND="${trimmed_prompt_command%\;};sdkman_auto_env"
+	fi
+
+	sdkman_auto_env
+fi

fish/functions/html_to_md.fish

@@ -0,0 +1,6 @@
+function html_to_md
+    set -l filename $argv[1]
+    set -l filename_md $(basename $filename .html).md
+    echo "transforming $filename => $filename_md..."
+    pandoc -f html -t markdown $filename -o $filename_md
+end

fish/functions/sdk.fish

@@ -0,0 +1,42 @@
+# Wrapper function for SDKMAN!
+
+# Copyright (c) 2018-2023 Raphael Reitzig
+# MIT License (MIT)
+# https://github.com/reitzig/sdkman-for-fish
+
+function sdk -d "Manage SDKs"
+    # Guard: SDKMAN! needs to be installed
+    if not test -f "$__fish_sdkman_init"
+        # Propose to install SDKMAN!
+
+        function read_confirm
+            while true
+                read -l -P "$argv[1] [y/N] " confirm
+
+                switch $confirm
+                case Y y
+                    return 0
+                case '' N n
+                    return 1
+                end
+            end
+        end
+
+        if read_confirm "You don't seem to have SDKMAN! installed. Install now?"
+            if not which curl > /dev/null
+                echo "curl required"
+                return 1
+            end
+            if not which bash > /dev/null
+                echo "bash required"
+                return 1
+            end
+
+            curl -s "https://get.sdkman.io" | bash | sed '/All done!/q'
+            echo "Please open a new terminal/shell to load SDKMAN!"
+        end
+    else
+        # Declare the _actual_ sdk command for fish
+        __fish_sdkman_run_in_bash "source \"$__fish_sdkman_noexport_init\" && sdk $argv"
+    end
+end

fish/functions/source_env_file_vars.fish

@@ -0,0 +1,5 @@
+function source_env_file_vars
+    for line in (cat $argv[1] | rg '^[^#\s]')
+        set -gx (string split '=' -m 1 -- $line)
+    end
+end